Tengo un mapa anidado así:

{:A {:B {:A {:B {:A {:B 0}}}}}}

Quiero contar las ocurrencias del par [: A: B] para que en el caso anterior, el resultado sea 3.

Mi idea inicial era usar clojure.walk/postwalk para recorrer el mapa e incrementar un contador.

¿Hay una forma más óptima de lograr esto?

0
Edmond 22 ene. 2018 a las 15:13

3 respuestas

La mejor respuesta

tree-seq funciona bien en este caso:

(defn count-ab [data]
  (->> data
       (tree-seq coll? seq)
       (keep #(get-in % [:A :B]))
       count))

user> (def data {:A {:B {:A {:B {:A {:B 0}}}}}})
#'user/data

user> (count-ab data)
3

user> (def data-1 {:A {:B {:C {:A {:B {:A {:B 0}}}}}}})
#'user/data-1

user> (count-ab data-1)
3

user> (def data-2 {:A {:X {:A {:B 100}}
                       :B {:C {:A {:B {:A {:B 0}}}}}}})
#'user/data-2

user> (count-ab data-2)
4
4
leetwinski 22 ene. 2018 a las 20:31

Debido a que es un mapa anidado, mi idea pragmática es atravesar recursivamente y contar:

(defn do-count [m]
   (loop [m m
          counter 0]
       (if-let [m* (get-in m [:A :B])]
           (recur m* (inc counter))
           counter)))


(do-count {:A {:B {:A {:B {:A {:B 0}}}}}}) ;==> 3
1
Minh Tuan Nguyen 22 ene. 2018 a las 12:45

Sugeriría escribir una función para convertir el mapa profundamente anidado en un mapa plano marcado por caminos

 (defn flatten-map
  "unwind deeply nested map into map of paths and vals"
  ([m] (into {} (flatten-map [] m)))
  ([path m]
   (if (map? m)
     (mapcat (fn [[k v]]
               (flatten-map (conj path k) v))
             m)
     [[path m]])))

Puede usar esto para contar las teclas adyacentes [: a: b] como esta

(->> {:A {:B {:A {:B {:A {:B 0}}}}}}
     flatten-map
     keys 
     (mapcat #(partition 2 1 %))
     (filter #(= [:A :B] %))
     count)
0
Ben Hammond 22 ene. 2018 a las 16:07